Quick elements of perl programming

Character String

• Strings are sequences of characters
• enclose the string with double-quotes or single-quotes to identify the beginning and ending of the string.

  Examples:
  "banjo", ' fiddle', "Pick'n Grin", 'Pick\'n Grin', "ATGTTATACG", "1 + 2 + 3", ' ', ''

• backslash (\) can be used to ``escape'' special meaning of quotes.

Exercises:

Let's see the differences between double- and single-quotes.

1. Make a small perl scripts which prints out the following strings. Make sure to print "\n" so that one string per line is printed.

   "Pick'n Grin", 'Pick\'n Grin', "ATGC\n", 'ATGC\n', '"\t"\n', "\"\t\"\n", '"'

2. How do you make a text string containing backslash (\)? Modify the script to print this out.

Note that single quotes are more literal, and it does not ``interprete'' many special or escape characters. Inside of single quotes, only two special characters can be used. What are these two?

Variable assignment

• In programming, you frequently make a container (variable), and put things (assgin values) in it.

     $x = 4 ; 
     $x = $x - 2 ;
  

  

• $ in front of variable name indicates that this is a simple scalar variable (more later).

• Assignment with a character string.

  #!/usr/bin/perl -w
  $message = "5 beer, please.\n";
  print ($message);
  exit;
  

  This program will do exactly same as the previous version without a variable:

  print ("5 beer, please.\n");
  

• = means assignment. Distinguish it from ``eqaul'' sign in mathematical equations.

  $x=$x+2

  This dosn't make a mathematical sense, does it?

• You can use whatever names for the variables (containers).

    $numSeqsFromFish = 2 ;
    $SCREAMER100 = 0 ;
    $buZZ_bEE = 4 ;
  

• Allowed characters and lengths for a variable name:
  • Alphabet: a-z, A-Z (it can be European characters)
  • Numbers: 0-9, but you can't start a variable name with a digit.
  • underscore: _
  • Length: 1 character or more, it can be pretty long
  • Case sensitive: $var1 is a different variable from $Var1.
  • It is a good practice to start with a lower case letter.

• Use self-explanatory name without being too verbose.

    $this_variable_contains_length_of_ADH_gene_before_splicing = 589;
    $popSize = 100 ;
    $ocRate = 0.3 ;
  

Example of printing character strings

Concatenate two DNA sequences:

#!/usr/bin/perl -w
  
$seqA = "ATATA";
$seqB = "GCGCG";

# concatenating 2 seqs
print "1st method:\t", $seqA, $seqB, "\n";

$joinedSeq = "$seqA$seqB";
print "2nd method:\t$joinedSeq\n";

$joinedSeq = $seqA . $seqB;   # using concatenate operator (.)
print "3rd method:\t", $joinedSeq,"\n";

exit;

• # indicates comment. Anything behind # to the end of the line is ignored
• You can combine strings, variables, and expressions with comma (,) in the print statement. The followings are ok, too:

  print "5 + 6 = ", 5+6, "\n";
  print "2/3 = ", 2/3, "\n";
  

• The double quotes allow the variables in the string to be replaced with their values (string interpolation)

    $joinedSeq = "$seqA$seqB";

  • Interpolation means, anything that Perl recognizes as a variable gets replaced by the value of that variable.

  • Sometime you need to use the following form (curly braces around the variable name):

    $seqA = "${seqA}nnn";
    

    If you write "$seqAnnn", perl thinks that there is a variable called $seqAnnn, instead of adding ``nnn'' at the end of $seqA

• The single quotes (') prevent string interpolation and conversion of special characters (e.g. \n and \t).

  Try adding the following line before exit; statement to confirm this.

  print 'single quotes: $seqA$seqB\n';
  

• Exercises:
  Make a small program to do the following steps:
  1. Assign your name to $var1
  2. Assign a string, "is a great perl hacker", to $stringVar
  3. Using the three methods of concatenating the two variable, let the program tell you the truth (i.e. the program should print out that you are a good programmer).

Basic operators

+, -, *, /	Arithmetic operators
$a % $b	Modulus
$a ** $b	Raises $a to the power of $b
$a . $b	Concatenates two strings.
(some operation)	The operation in the parentheses get executed first
$a = $b	Assignment
$a += $b	same as $a = $a + $b.
-=, *=, /=, .=	Similar to above
$a++, $a--	Incremeny, decrement by one.
"abc" x 4	String multiplication (results in "abcabcabcabc")

Exercises:

Make the following perl script. Pay attention to what the opertors are doing to the variables (containers).

  $a = 16;
  print "$a\n";

  $a += 4;
  print "Added 4: $a\n";

  $b = $a;
  $mod = $b % 4;
  print "$b mod 4 = $mod\n";

  $a--;
  print "decremented: $a\n";

  $codon = "ATG";
  $codon .= " CCC"; 
  print "$codon\n";

Perl variable types

Perl has three main variable types:

• Scalars: this variable stores a single value (like a cat basket above)
• Arrays: this variable stores multiple values (like a compartmentized basket)
• Hashes: extremely useful, see below

Scalars

  $popSize = 1000;      # integer
  $probability = 0.9;   # floating point
  $smallVal = 2.11E-2;  # floating point with engineering notation
  $name = "Bob";        # character string

• Scalar values can be strings, integers or floating point numbers
• Perl will automatically convert between them as required.

     $var1 = "9";
     $var2 = "10";
     print $var1 / $var2, "\n";
  

• No need to pre-declare your variable types (e.g. int, double, etc).

Arrays

• An array represents a list of values:

  

    @animals = ("camel", "llama", "owl");
    @numbers = (23, 42, 69);
    @mixed   = ("camel", 42, 1.23);
  

• Arrays are zero-indexed. Here's how you get elements in an array:

  print $animals[0];              # prints "camel"
  print $animals[1];              # prints "llama"
  

  The elements we're getting from the array start with a $ because we're getting just a single value out of the array -- you ask for a scalar, you get a scalar.

  Exercises:
  What happens if you negative integer (e.g. -1 or -2) as the indices? Try printing them out.

• Printing array

  Try following, and see the difference:

  print @animals;    # Array NOT enclosed in double quotes
  print "\n";
  # interpolating an array into char string
  print "@animals";  # Array enclosed in double quotes
  print "\n";
  

• Other ways to create an array
  • Method 1: sparse array

    $trees[0] = 'spruce';
    $trees[1] = 'birch';
    $trees[2] = 'aspen';
    $trees[99] = 'alder';
    

    This will create an array @trees.

  • Method 2: qw(), quoted by white space, or quoted words

    @animals = qw( camel llama owl );
    

    This creates exactly same array as defined above.
    You can reduce typing lots of quote marks and commas.

  • Method 3: sequential integers

    @seqNum = 11..15;
    

    exactly same as:

    @seqNum = (11, 12, 13, 14, 15);
    

  • Exercises:
    • With @trees array, what happens if you print 50-th element? How about printing an element with -100?

    • Check if qw() will do interpolation. In other words, is it similar to (') or (")?

    • With the method 3, what happens if you use alphabets instead of integers?

• Modifying a value of an array

  Try the following, and note how elements of @a changes at each step:

  @a = (1, 2, 3, 4, 5);
  print "orig: @a\n";
  
  $a[4] = 10;
  print "1st : @a\n";
  
  $a[2] = $a[1] ** $a[2];
  print "2nd : @a\n";
  
  $a[-2] = $a[1];
  print "3rd : @a\n";
  

• The special variable $#array tells you the index of the last element of an array:

  print $mixed[$#mixed];    # last element, prints 1.23

• Size of an array
  • $#array + 1 can tell you how many items there are in an array.
  • As it happens, using @array where Perl expects to find a scalar value ("in scalar context") will give you the number of elements in the array:

    $numAnimals = @animals;
    
    if (@animals < 5) { ... }
    

• To get multiple values from an array (array slice):

  @subset = @animals[0,1];           # gives ("camel", "llama");
  @subset = @animals[0..2];          # gives ("camel", "llama", "owl");
  @subset = @animals[1..$#animals];  # gives all except the first element
  

Hashes

Similar to arrays because a hash can contain multiple data (values).

Different from array because hash values are looked up (indexed) by names (keys), instead of numerical indecies in arrays.

Extremely useful, and central to Perl programming.

• A hash represents a set of key/value pairs:

    %fruit_color = ("apple", "red", "banana", "yellow");
      

  Following will achieve the same, but it looks nicer:

    %fruit_color = (
      "apple"  => "red",
      "banana" => "yellow"
    );
  

  It's like a look-up table.

• To get a hash elements:

  $fruit_color{"apple"};           # gives "red"
  

  NOTE: the entire hash table is refered as %fruit_color with %. But to access an element which is scalar, you use ``$''.

  You can use expression or variable names as the key. If the key is not a simple character string, interpolation and evaluation of the expression occurs BEFORE the look-up.

    $thisFr = 'apple';
    print "Color of $thisFr is $fruit_color{$thisFr}\n"; # interpolation
    
    $name = 'ana';
    $frCol = $fruit_color{'ban' . $name};
  

• Adding key and value combo to hash:

  %sound = ();    # empty hash table
  $sound{'ukulele'} = 'happy';
  $sound{'banjo'} = 'loud';
  

• Deleting a key/value pair.

  delete $sound{'ukulele'};
  

  It removes the given key, and the corresponding value from the hash %sound.

• You can get lists of keys and values with keys() and values() functions.

    @fruits = keys(%fruit_colors);   # ("banana", "apple")
    @colors = values(%fruit_colors); # ("yellow", "red")
      

• The order of the arrays created by keys() and values() is not preserved.
• The key has to be unique. But values does not have to be unique.

  This is NOT OK because when you access $fruit_color{"apple"}, perl doesn't know if you want the first one or second one.

    %fruit_color = (
      apple  => "red",
      apple => "green",
      banana => "yellow"
    );
  

  Duplicated values are OK:

    %fruit_color = (
      apple  => "red",
      banana => "yellow",
      lemon => "yellow",
    );
  

Hash Exercise/Example

Type in the following program, and think what it is doing.

#!/usr/bin/perl -w

my %recognitionSite = (
  "EcoRI" => "G^AATTC",
  "HindIII" => "GG^CC"
);

$recognitionSite{"AatII"} = "GACGI^C";  # adding more key/value combos to
$recognitionSite{"XbaI"} = "T^CTAGA";   # the hash

my @knownEnzymes = keys(%recognitionSite);
print "Known enzymes: ", join(",", @knownEnzymes), "\n";

for( ; ; ) {
  print STDERR "Restriction Enzyme?: ";
  my $enzyme =  <STDIN>;
  chomp ($enzyme);  # remove the newline;

  print "Recognition Site = $recognitionSite{$enzyme}\n\n";
}

exit;

Note: join function: join($glue, @list) takes a list of values, and ``glue'' them with $glue string and return a scalar (string).

Variable Scopes

• Remember local and global variables in C? The global variables can be accessed from anywhere, but the local variables are known within a function.
• To make private variables (equivalent to local scope of C), we use my keyword at the first time this variable is used.

  my $var = "value";

• You can set several private variables by one statement:
  my ($a, $b, $c, $d) = (1,2,3,4);

• If you do not use my at the first time when it is used, the variable has global scope.

  $globalVar = "Everyone knows me.";

• As with C, it's a better practice to make variables as private (local) as possible.

• There is another scope called ``local'' in Perl, which is slightly different (it's not as ``local'' as my). But you can live without knowing about it. Most of the time I use either global or my variables.

Homework

Create a directory with your first name inside of /scratch/compbio/hw. Then create a directory called hash in there (e.g. /scratch/compbin/hw/naoki/hash for me). After completing the following homework, please copy your 3 scripts into this directory.

1. Make an array with 4 elements: ("AAA","AAT","AAG", "AAC"). Then print out the last element.

2. Make a hash, whose keys are the name of species and values are their DNA sequences. You can use the following fake sequence data:
   

   species	DNA sequence
   camel	ATGCCTATTGGA
   llama	ATGACTACCGGC
   owl	ATGAAGAGGGTC

   Then print out the sequence of llama.
   Then concatenate the three sequences (store it in a new scalar variable), and print out the concatenated sequence.

3. Can you make a program which will ask for 3 nucleotides, and print out the amino acid corresponding to the codon? You can basically modify the example program (restriction site) used in the hashes section.