Flow control

Conditional and looping constructs are similar to C, but there are some differences in details.

if

• Basic form

  if (condition1) {
    statement1a;
    statement1b;
  } elsif (condition2) {
    statement2a;
    statement2b;
  } else {
    statement3a;
    statement3b;
  }
  
  nextStatement;
  

  • Example:

      print "Give me a number?: ";
      my $number = <STDIN>;
    
      print "\n";
      if ($number > 0) {
        print "$number is positive\n";
      } elsif ($number < 0) {
        print "$number is negative\n";
      } else {
        print "$number is not positive nor negative\n";
      }
      exit;
    

• elsif and else are optional. You can also have many elsif.

  if (conditon1) {
    statement1;
  }
  
  if (condition1) {
    statement1;
  } else {
    statement2;
  }
  

  All of the above are ok.

• Note that it uses elsif instead of else if in C.

• The braces are required after if in Perl.

  In C, braces can be omitted if there is one statement (one-line conditional block).

  if (a == 1)
    printf("a is 1\n");
  

  But in Perl,

  if ($a == 1) {
    print ("$a is 1\n");
  }
  

• But you can write a one-liner conditional block in the following way:

  print  ('$a is 1') if ($a == 1);
  print "I'm hungry.\n" if ($food == 0);
  

  This reads more English-like.

• Exercise:
  • Create a program which will ask for a number and returns the absolute value.
  • Try the following program, change the value of $x (e.g., -200, -0.9, 0, 0.0001, 1, 200, "abc", ""), and think when the following condition becomes true or false.

    my $x = 1;
    
    if ($x) {
      print "$x is True\n";
    } else {
      print "$x is False\n";
    }
    

Logical operator

Comparison in Perl is a little more complicated.

• Numeric comparison

  ==	equality
  !=	inequality
  <	less than
  >	greater than
  <=	less than or equal
  >=	greater than or equal

• String comparison

  eq	equality
  ne	inequality
  lt	less than
  gt	greater than
  le	less than or equal
  ge	greater than or equal

  In string comparison, it is comparing the two expression alphabetically.

  Try the following to clarify what is meant by comparing strings:

   print "yes" if ("abc" ge "abd");
  

• Why do we need these two separate comparisons?

  The following example should illustrate the difference.

  my $a = 100;
  my $b = 99;
  
  if ($a > $b) {
    print "a is bigger\n";
  } else {
    print "b is bigger\n";
  }
  
  if ($a ge $b) {
    print "a is bigger alphabeticcally\n";
  } else {
    print "b is bigger alphabetically\n";
  }
  

  Sometimes, you want to sort numerically. Other times, you want to sort alphabetically. Perl needs the two comparison mechanisms since Perl can flexibly convert integer, floating points, and strings.

Boolean logic

• Same as C:

  &&	and
  ||	or
  !	not

• Example:

  if ( $a > 0 && (! $b)) {
    ...
  }
  

unless

• There is another conditional, which isn't in C.

  unless (condition) {
   ...
  }
  

• This is same as if(! condition).
• Example:

  unless ($a > 0) {
   ...
  }
  if (! ($a > 0) {
   ...
  }
  if ($a <= 0) {
   ...
  }
  

  All of these 3 conditionals will do exactly same thing.

for

Exactly like C:

• General form of for loop

  for ( initial; condition; increment) {
    statement1;
    statement2;
  }
  

• Simple example:

  for ($i = 0; $i < 10; $i++) {
    print "$i\n";
  }
  

• What actually happens:
  1. initial is evaluated ($i = 0;)
  2. condition is evaluated ($i < 10)
  3. If condition is NOT met, the for loop terminates, and the process moves to the next statements after the end of for loop.
  4. If condition is met, statement1, 2, ... inside of the for loop is executed (print "$i\n";).
  5. increment is evaluated ($i++;), and goes to step 2.

• Another example: guess what would be printed?

  my @arrA = ();
  my $i;
  $max = 10;
  for ($i=0; $i < $max; $i++) {
    $arrA[$i] = $i * 3;
  }
  print "@arrA", "\n";
  

• Exercise:
  1. Create an array of a DNA sequence (@seq):

     my @seq = qw( A T G C C C T T T );
     

     Using for loop, create an array, @revseq, which is the reverse of this seuqnce. Then print this array without spaces (i.e., you should print out TTTCCCGTA).

  2. Create an infinite loop, which will keep printing 'Z' forever.

foreach

• This looping constuct can be more useful for some occasions.

  #!/usr/bin/perl -w
  my @fuzz = ('dog','cat','ferret');
  
  foreach my $item (@fuzz) {
    print "$item\n";
  }
  
  exit;
  

• The following is same as the C-type for() loop above:

  foreach my $i (0..($max-1)) {
    ...
  }
  

• Useful to print out hashes.

  foreach my $key (sort(keys %hashTbl)) {
    print "$key => $hashTbl{$key}\n";
  }
  

• Exercise: Modify the program you created in the exercise from the previous section, where you made a hash table of llama, camel, and owl DNA sequence. Following the above example to print out the contents of hash table, print out the sequence data in FASTA format:

  >camel
  ATGCCTATTGGA
  >llama
  ATGACTACCGGC
  >owl
  ATGAAGAGGGTC
  

• Count example: Using a hash to count events

  #!/usr/bin/perl -w
  
  my @vote = ('y', 'n', 'n', 'y','n');
  my %cnter;
  
  foreach my $yn (@vote) {
    $cnter{$yn} ++;
  }
  
  print "$cnter{'y'} Yes votes,  $cnter{'n'} No votes\n";
  exit;
  

while

Same as in C:

• General form:

  while( condition ) {
   ...
  }
  

  1. Check the condition
  2. If the condition is true execute the statements within {...}.
  3. If the condition is not true, skip the statements within {...}.
  4. Go back to step 1, and keep looping until condition is not met.

• Example:

  #!/usr/bin/perl
  
  my $cntr = 10;
  while ($cntr > 0) {
    print "In loop: ";
    print "counter is $cntr\n";
    $cntr -= 3;
  }
  
  print "Outside of while loop: counter is $cntr\n";
  exit;
  

• Exercise: Rewrite the following code with while loop instead of for loop:

  for ($i = 2; $i < 20; $i++) {
    my $mod = $i % 7;
    print "$i % 7 = $mod\n";
  }
  

Homework:

1. Make a program which will keep asking an integer as the input forever (use an infinite loop), and then calculate and print the factorial (!) of the given integer.

   A factorial of x is defined as x! = x * (x-1) * ... * 2 * 1.

2. Starting from the following code, make a program to count the base frequency:

   #!/usr/bin/perl -w
   my $seqString = "AGGTGACCTTAGGCTTATAGCTATTA";
   
   ### create an array: each element is a single base.
   my @bases = split(//, $seqString);
   

   The split command creates an array by splitting the character string into each character. In other words, the array @bases become ('A', 'G', 'G', 'T', ....).

   Count how many 'G' or 'C' this sequence contains (GC content), and print out the results.

   Hint 1: You want to loop through all elements of the array, and check whether each nucleotide is equal to 'G' or 'C' (remember '||' means OR?). If it matches, you want to increment the counter. After you are done looping through all elements, you can print out the value of the counter.

   Hint 2: There are several way of looping through all elements of an array.

   foreach $nucleotide (@bases) { 
      ... 
   }
   

   might be the easiest. The variable $nucleotide become 'A' at first, then it become 'G' in the 2nd loop.

3. Can you modify this program to print out base composition? You want to print out the percent of A, T, G, and C. You have to count occurences of A, T, G, and C. Then divide the occurence by the total sequence length.